HỆ THỐNG TRUY CẬP KIỂM SOÁT DỰA TRÊN RFID SỬ DỤNG VI ĐIỀU KHIỂN 8051

HỆ THỐNG TRUY CẬP KIỂM SOÁT DỰA TRÊN RFID

SỬ DỤNG VI ĐIỀU KHIỂN 8051

Trong dự án này, chúng ta sẽ xây dựng 1 hệ thống kiểm soát truy cập dựa trên RFID sử dụng Bộ điều khiển vi mô 8051. Các hệ thống tương tự như khóa cửa hay  hệ thống quản lý truy cập dựa trên RFID.. Nếu bạn đến bất kì các bệnh viện hoặc công ty lớn nào, bạn sẽ thấy cách họ sử dụng khóa dựa trên RFID để hạn chế quyền truy cập vào một số khu vực. Trong bệnh viện, chỉ nhân viên bệnh viện có thẻ RFID được phê duyệt mới có thể truy cập khu vực chăm sóc đặc biệt và các khu vực bị hạn chế như vậy. Vì vậy, hãy bắt đầu xây dựng hệ thống!

Trước khi đọc tiếp, bạn cần hiểu đầy đủ Cách Giao tiếp của Bộ đọc RFID đến Vi điều khiển 8051. Hãy đọc bài viết này trước khi cố gắng xây dựng 1 hệ thống kiểm soát truy cập dựa trên RFID hoàn chỉnh.

Mô tả

Khóa cửa dựa trên RFID hoặc Hệ thống kiểm soát truy cập dựa trên một số khái niệm đơn giản. Chúng tôi lưu trữ một bộ dữ liệu thẻ RFID trong hệ thống của chúng tôi, giả sử 3 hoặc 10 dữ liệu thẻ RFID. Khi người có thẻ RFID phù hợp (tương thích với dữ liệu được tải sẵn trong chương trình / hệ thống của chúng tôi) đến và quẹt thẻ RFID thì quyền truy cập sẽ được cấp. Còn khi người có thẻ RFID sai (có dữ liệu không được tải trong chương trình/hệ thống của chúng tôi) quẹt thẻ RFID thì quyền truy cập sẽ bị từ chối.

Sơ đồ bên trên là mạch giao tiếp của module RFID với vi điều khiển 8051. Mã ID duy nhất trong thẻ RFID được đọc bởi mạch và được hiển thị trên màn hình LCD 16 x 2. Chân Tx của module RFID được nối với chân P3.5 của vi điều khiển. Bộ vi điều khiển nhận dữ liệu gửi từ module RFID thông qua kênh này. Nút nhấn S1, tụ C1 và điện trở R1 tạo thành mạch reset. Tụ điện C2, C3 và bộ dao động X1 được nối với mạch reset.

Chương trình

RS EQU P2.7

RW EQU P2.6

E  EQU P2.5

FLG EQU 40H

SEL EQU 41H

ORG 000H

CLR P2.0

MOV TMOD,#00100001B

MOV TH1,#253D

MOV SCON,#50H

SETB TR1

ACALL LCD_INIT

MOV DPTR,#TEXT1

ACALL LCD_OUT

ACALL LINE2

MOV DPTR,#TEXT2

ACALL LCD_OUT

MAIN:ACALL LCD_INIT

     MOV DPTR,#TEXT1

     ACALL LCD_OUT

     ACALL LINE2

     MOV DPTR,#TEXT2

     ACALL LCD_OUT

     ACALL READ_TAG

     CLR REN

     ACALL LINE2

     ACALL CHECK_PASSWORD

     ACALL DELAY1

     SETB REN

     SJMP MAIN

LCD_INIT: MOV DPTR,#INIT_COMMANDS

          SETB SEL

          ACALL LCD_OUT

          CLR SEL

          RET     

LCD_OUT:  CLR A

           MOVC A,@A+DPTR

           JZ EXIT

           INC DPTR

           JB SEL,CMD

           ACALL DATA_WRITE

           SJMP LCD_OUT

CMD:      ACALL CMD_WRITE

           SJMP LCD_OUT

EXIT:     RET         

LINE2:MOV A,#0C0H

    ACALL CMD_WRITE

    RET  

 READ_TAG:  MOV R0,#12D

           MOV R1,#160D

               WAIT:JNB RI,WAIT

           MOV A,SBUF

           MOV @R1,A

           INC R1

           CLR RI

           DJNZ R0,WAIT

           RET

CHECK_PASSWORD:          CLR FLG

                        MOV R2,#12D

                        MOV R1,#160D

                        MOV DPTR,#PASS1

            REPEAT: CLR A

                        MOVC A,@A+DPTR

                        XRL A,@R1

                        JNZ CHECKNEXT

                        INC R1

                        INC DPTR

                        DJNZ R2,REPEAT

                        ACALL LINE2

                        MOV DPTR,#TEXT3

                        ACALL LCD_OUT

                        SETB P2.0

                        RET

CHECKNEXT: JB FLG,FAIL

           MOV R2,#12D

           MOV R1,#160D

           MOV DPTR,#PASS2

           SETB FLG

           SJMP REPEATa

FAIL:ACALL LINE2

     MOV DPTR,#TEXT4

     ACALL LCD_OUT

     CLR P2.0

     RET

DELAY1:MOV R3,#46D

BACK:  MOV TH0,#00000000B  

       MOV TL0,#00000000B  

       SETB TR0            

HERE1: JNB TF0,HERE1        

       CLR TR0            

       CLR TF0            

       DJNZ R3,BACK

       RET

CMD_WRITE: MOV P0,A

    CLR RS

    CLR RW

    SETB E

    CLR E

    ACALL DELAY

    RET

DATA_WRITE:MOV P0,A

    SETB RS

    CLR RW

    SETB E

    CLR E

    ACALL DELAY

    RET

DELAY: CLR E

    CLR RS

    SETB RW

    MOV P0,#0FFh

    SETB E

    MOV A,P0

    JB ACC.7,DELAY

    CLR E

    CLR RW

    RET

INIT_COMMANDS:  DB 0CH,01H,06H,83H,3CH,0   

TEXT1: DB "RFID ACCESS",0 

TEXT2: DB "Swipe TagS..",0

TEXT3: DB "Access allowed",0

TEXT4: DB "Access denied",0

PASS1: DB "18008DC02E7B"

PASS2: DB "7500511ECDF7"

    END

Bộ KIT dự án - Hệ thống kiểm soát truy cập RFID

asadasd

asdasdasd